Check If C Function Has Expected Prototype using CMake

When developing cross-platform C or C++ applications, you may run into situations where a function exists on one system but not on another, or it may have a slightly different signature. To write portable code, it's often necessary to verify that a function exists and has the expected prototype before using it. This tutorial demonstrates how to check if a C function has expected prototype using CMake.

CMake offers the check_prototype_definition command, which can test whether a particular function exists with the exact signature you expect.

Here's a simple CMakeLists.txt demonstrating how to check for a function prototype:

cmake_minimum_required(VERSION 3.27)
project(myapp)

set(CMAKE_CXX_STANDARD 17)

include(CheckPrototypeDefinition)

check_prototype_definition(
        gethostbyaddr
        "struct hostent *gethostbyaddr(const void *addr, socklen_t len, int type)"
        "0"
        "netdb.h"
        HAVE_LINUX_GETHOSTBYADDR
)
if (HAVE_LINUX_GETHOSTBYADDR)
    # ...
endif ()

add_executable(${PROJECT_NAME} main.cpp)

When using check_prototype_definition, CMake generates a small test program that declares the function with the specified prototype and includes the given headers. The <return> parameter (in our case 0) is the value the function returns in the test program, letting CMake check that the return type matches the expected type. If the test compiles successfully, CMake sets the designated variable to TRUE, which can then be used in the CMake scripts or as a preprocessor definition to conditionally enable code depending on the function's presence and correct signature.

You can perform similar checks by listing multiple headers using ; separator:

# ...

include(CheckPrototypeDefinition)

check_prototype_definition(
        getpwent
        "struct passwd *getpwent(void)"
        "0"
        "unistd.h;pwd.h"
        HAVE_LINUX_GETPWENT
)
if (HAVE_LINUX_GETPWENT)
    # ...
endif ()

# ...

By default, check_prototype_definition command prints messages during configuration like:

-- Checking prototype gethostbyaddr for HAVE_LINUX_GETHOSTBYADDR
-- Checking prototype gethostbyaddr for HAVE_LINUX_GETHOSTBYADDR - True

If you prefer a cleaner output during configuration, enable quiet mode by using the variable CMAKE_REQUIRED_QUIET before performing the checks:

# ...

set(CMAKE_REQUIRED_QUIET TRUE)

include(CheckPrototypeDefinition)

check_prototype_definition(
        gethostbyaddr
        "struct hostent *gethostbyaddr(const void *addr, socklen_t len, int type)"
        "0"
        "netdb.h"
        HAVE_LINUX_GETHOSTBYADDR
)

# ...